cmake使用教程（三）-安装、测试、系统自检

【cmake系列使用教程】

cmake使用教程（一）-起步

cmake使用教程（二）-添加库

cmake使用教程（三）-安装、测试、系统自检

这个系列的文章翻译自官方cmake教程：cmake tutorial，但是又不会仅仅停留在官方教程。本人作为一个安卓开发者，实在是没有linux c程序开发经验，望大佬们海涵。教程是在macos下完成，大部分linux我也测试过，有特殊说明的我会标注出来。本教程基于cmake-3.10.2，同时认为你已经安装好cmake。

本节将为我们的项目添加安装规则和测试支持。此处仅讲解教程中添加的一些规则，后续有详细章节讲解定制自己的安装规则。只适用于macos和linux。

设置安装规则

安装规则相当简单。对于mathfunction库，我们设添加了这个库，通过将以下两行添加到mathfunction的CMakeLists.txt中来安装头文件和静态库:

install (TARGETS MathFunctions DESTINATION bin)
install (FILES MathFunctions.h DESTINATION include)

然后根目录下的CMakeLusts.txt文件中添加如下行,用来安装可执行文件和配置文件：

# add the install targets
install (TARGETS Tutorial DESTINATION bin)
install (FILES "${PROJECT_BINARY_DIR}/TutorialConfig.h"        
         DESTINATION include)

注意上边install的第一个参数和第三个参数。

TARGETS包含六种形式：ARCHIVE, LIBRARY, RUNTIME, OBJECTS, FRAMEWORK, BUNDLE。注意Mathfunction安装的是LIBRARY，而根目录下的可执行文件是RUNTIME类型。

FILE 将给定的文件复制到指定目录。如果没有给定权限参数，则由该表单安装的文件默认为OWNER_WRITE、OWNER_READ、GROUP_READ和WORLD_READ。

TARGETS和FILE可指定为相对目录和绝对目录。

DESTINATION在这里是一个相对路径，取默认值。在unix系统中指向 /usr/local 在windows上c:/Program Files/${PROJECT_NAME}。

也可以通过设置CMAKE_INSTALL_PREFIX这个变量来设置安装的路径，那么安装位置不指向/usr/local，而指向你所指定的目录。

cmake .
make
makeinstall

执行完毕后即安装了软件。

示例中指向的安装地址如下表所示:

添加测试

添加测试也非常简单，在根目录下的CMakeLists.txt文件最后添加如下代码来测试输入参数后产生的结果是否正确。

include(CTest)

# does the application run
add_test (TutorialRuns Tutorial 25)
# does it sqrt of 25
add_test (TutorialComp25 Tutorial 25)
set_tests_properties (TutorialComp25 PROPERTIES PASS_REGULAR_EXPRESSION "25 is 5")
# does it handle negative numbers
add_test (TutorialNegative Tutorial -25)
set_tests_properties (TutorialNegative PROPERTIES PASS_REGULAR_EXPRESSION "-25 is 0")
# does it handle small numbers
add_test (TutorialSmall Tutorial 0.0001)
set_tests_properties (TutorialSmall PROPERTIES PASS_REGULAR_EXPRESSION "0.0001 is 0.01")
# does the usage message work?
add_test (TutorialUsage Tutorial)
set_tests_properties (TutorialUsage PROPERTIES PASS_REGULAR_EXPRESSION "Usage:.*number")

构建项目完成后，可以运行ctest命令行工具来运行测试。第一个测试只是验证应用程序是否正常运行，没有发生崩溃，并且返回值是0。这是CTest测试的基本形式。接下来的几个测试都使用PASS_REGULAR_EXPRESSION测试属性来验证测试的输出是否包含特定的字符串。

如果您想要添加许多测试来测试不同的输入值，您可以考虑创建如下的宏(相当于函数):

#define a macro to simplify adding tests, then use it
macro (do_test arg result)
  add_test (TutorialComp${arg} Tutorial ${arg})
  set_tests_properties (TutorialComp${arg}
    PROPERTIES PASS_REGULAR_EXPRESSION ${result})
endmacro (do_test)
 
# do a bunch of result based tests
do_test (25 "25 is 5")
do_test (-25 "-25 is 0")

构建项目后执行ctest可得到如下结果：

 ~/Desktop/Tutorial/Step3/build/ ctest
Test project /Users/saka/Desktop/Tutorial/Step3/build
    Start 1: TutorialRuns
1/5 Test #1: TutorialRuns .....................   Passed    0.00 sec
    Start 2: TutorialComp25
2/5 Test #2: TutorialComp25 ...................   Passed    0.01 sec
    Start 3: TutorialNegative
3/5 Test #3: TutorialNegative .................   Passed    0.00 sec
    Start 4: TutorialSmall
4/5 Test #4: TutorialSmall ....................   Passed    0.00 sec
    Start 5: TutorialUsage
5/5 Test #5: TutorialUsage ....................   Passed    0.00 sec

100% tests passed, 0 tests failed out of 5

Total Test time (real) =   0.03 sec

可以看到，测试全部通过。

添加系统自检

有时候我们可能会为多种平台开发程序，而有的平台包含某个库，有的平台不包含这个库，那么我们就可以通过系统自检来判断是使用平台系统提供的库还是自己编写的库。

下边我们将添加一些依赖于目标平台是否具有log和exp函数的代码。当然，几乎每个平台都有这些功能，但本教程假设它们不太常见。如果平台有log库，那么我们将使用它来计算平方根，而不适用mysqrt中的函数。

首先使用CheckFunctionExists.cmake宏来测试这些函数的是否存在。在顶级CMakeLists.txt文件中编写代码如下:

# does this system provide the log and exp functions?
include (CheckFunctionExists)
check_function_exists (log HAVE_LOG)
check_function_exists (exp HAVE_EXP)

然后在TutorialConfig.h.in中添加使用上边定义的变量的代码：

// does the platform provide exp and log functions?
#cmakedefine HAVE_LOG
#cmakedefine HAVE_EXP

有一点需要注意：log和exp的测试代码一定要在TutorialConfig.h的configure_file命令之前。configure.file命令会立即使用CMake中的当前设置配置文件。最后，在mysqrt函数中，我们可以提供一个基于log和exp的替代实现，如果它们在系统上可用以下代码可用:

// if we have both log and exp then use them
#if defined (HAVE_LOG) && defined (HAVE_EXP)
  result = exp(log(x)*0.5);
#else // otherwise use an iterative approach
  ...